feat: add `iced-builder-git` package

3 files changed, 89 insertions, 11 deletions

diff --git a/.SRCINFO b/.SRCINFO
new file mode 100644
index 0000000..9830e3d
--- /dev/null
+++ b/.SRCINFO
@@ -0,0 +1,22 @@
+pkgbase = iced-builder-git
+	pkgdesc = UI builder for iced, built with iced.
+	pkgver = 0.1.0.r201.g4881939
+	pkgrel = 1
+	url = https://github.com/pml68/iced-builder
+	arch = x86_64
+	license = GPL-3.0-or-later
+	makedepends = git
+	makedepends = cargo
+	depends = gcc-libs
+	depends = glibc
+	depends = openssl
+	optdepends = rustfmt: better code formatting
+	provides = iced-builder
+	conflicts = iced-builder
+	options = !lto
+	options = !strip
+	options = !debug
+	source = iced-builder::git+https://github.com/pml68/iced-builder.git
+	sha256sums = SKIP
+
+pkgname = iced-builder-git
diff --git a/PKGBUILD b/PKGBUILD
new file mode 100644
index 0000000..a735750
--- /dev/null
+++ b/PKGBUILD
@@ -0,0 +1,67 @@
+# Maintainer: pml68 <contact@pml68.dev>
+
+_pkgname=iced-builder
+pkgname=$_pkgname-git
+pkgver=0.1.0.r201.g4881939
+pkgrel=1
+pkgdesc='UI builder for iced, built with iced.'
+arch=(x86_64)
+url='https://github.com/pml68/iced-builder'
+license=('GPL-3.0-or-later')
+depends=(
+  gcc-libs
+  glibc
+  openssl
+)
+optdepends=('rustfmt: better code formatting')
+makedepends=(
+  git
+  cargo
+)
+options=('!lto' '!strip' '!debug')
+provides=("$_pkgname")
+conflicts=("$_pkgname")
+source=("$_pkgname::git+${url}.git")
+sha256sums=('SKIP')
+
+prepare() {
+  cd "${_pkgname}"
+  rm .cargo/config.toml
+
+  export RUSTUP_TOOLCHAIN=stable
+  cargo fetch --locked --target "$(rustc -vV | sed -n 's/host: //p')"
+}
+
+pkgver() {
+  cd "${_pkgname}"
+  printf "%s.r%s.g%s" \
+    "$(cargo pkgid | cut -d@ -f2)" \
+    "$(git rev-list --count HEAD)" \
+    "$(git rev-parse --short HEAD)"
+}
+
+build() {
+  cd "${_pkgname}"
+
+  export RUSTUP_TOOLCHAIN=stable
+  export CARGO_TARGET_DIR=target
+  export RUSTFLAGS="${RUSTFLAGS} --remap-path-prefix $srcdir=src"
+  cargo build --frozen --release
+}
+
+check() {
+  cd "${_pkgname}"
+
+  export RUSTUP_TOOLCHAIN=stable
+  export CARGO_TARGET_DIR=target
+  cargo test --frozen --release
+}
+
+package() {
+  cd "${_pkgname}"
+
+  install -Dm755 "target/release/${_pkgname}" "${pkgdir}/usr/bin/${_pkgname}"
+
+  install -Dm644 LICENSE "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
+  install -Dm644 "assets/linux/dev.pml68.${_pkgname}.desktop" -t "${pkgdir}/usr/share/applications"
+}
diff --git a/README.md b/README.md
deleted file mode 100644
index fc9dab3..0000000
--- a/README.md
+++ /dev/null
@@ -1,11 +0,0 @@
-# PKGBUILDs
-
-My personal PKGBUILDs.
-
-## Usage
-
-For available packages, check out the different branches; Each one contains a single package. For installation of a selected package, clone it with
-```sh
-$ git clone --branch <package_name> --single-branch https://github.com/pml68/PKGBUILDs <package_name>
-```
-Then you can enter the directory and install with your preferred tool (`makepkg`, `yay` etc.)