PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50

# shellcheck disable=SC2034,SC2154,SC2164
# Maintainer: Polesznyák Márk <contact@pml68.dev>

pkgname=hare-git
_pkgname=hare
pkgver=0.24.2.rc1.r449.g152798b
pkgrel=1
pkgdesc="The Hare systems programming language"
url="https://harelang.org"
arch=("x86_64" "aarch64")
license=("MPL2")
provides=("hare")
conflicts=("hare")
depends=(
  "qbe-git"
  "harec-git"
)
makedepends=(
  "scdoc"
  "git"
)
source=("${pkgname%-*}::git+https://git.sr.ht/~sircmpwn/hare")
sha256sums=('SKIP')

pkgver() {
  cd "$srcdir/$_pkgname"

  git describe --long --abbrev=7 2>/dev/null | sed 's/\([^-]*-g\)/r\1/;s/-/./g'
}

build() {
  cd "$srcdir/$_pkgname"

  cp "configs/linux.mk" config.mk
  export LOCALVER=arch
  make ARCH="$CARCH" PREFIX=/usr
}

check () {
  cd "$srcdir/$_pkgname"

  make ARCH="$CARCH" check
  HAREPATH=. .bin/hare test
}

package() {
  cd "$srcdir/$_pkgname"

  make ARCH="$CARCH" PREFIX=/usr DESTDIR="$pkgdir" install
}