blob: 7ae92862c8c4622f182a92ce3c3bffa190555494 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
|
# shellcheck disable=SC2034,SC2154,SC2164
# Maintainer: Adrián Pérez de Castro <aperez@igalia.com>
pkgname=qbe-git
pkgver=1.2.r62.g120f316
pkgrel=1
pkgdesc='Small embeddable C compiler backend'
url=http://c9x.me/compile/
arch=(x86_64 aarch64)
license=(custom:MIT)
provides=(qbe)
conflicts=(qbe)
depends=(glibc)
makedepends=(git)
source=("${pkgname}::git://c9x.me/qbe.git")
sha256sums=('SKIP')
pkgver () {
cd "${pkgname}"
git describe --tags --long 2>/dev/null | sed 's/^v//;s/\([^-]*-g\)/r\1/;s/-/./g'
}
build () {
cd "${pkgname}"
make
}
check () {
cd "${pkgname}"
make check
}
package (){
cd "${pkgname}"
install -Dm755 qbe "${pkgdir}/usr/bin/qbe"
install -Dm644 LICENSE "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
install -m755 -d "${pkgdir}/usr/share/doc/${pkgname}"
install -m755 -t "${pkgdir}/usr/share/doc/${pkgname}" doc/*.txt
}
|
