1 files changed, 50 insertions, 0 deletions
diff --git a/PKGBUILD b/PKGBUILD
new file mode 100644
index 0000000..ef2244a
--- /dev/null
+++ b/PKGBUILD
@@ -0,0 +1,50 @@
+# shellcheck disable=SC2034,SC2154,SC2164
+# Maintainer: Polesznyák Márk <contact@pml68.dev>
+
+pkgname=hare-git
+_pkgname=hare
+pkgver=0.24.2.rc1.r449.g152798b
+pkgrel=1
+pkgdesc="The Hare systems programming language"
+url="https://harelang.org"
+arch=("x86_64" "aarch64")
+license=("MPL2")
+provides=("hare")
+conflicts=("hare")
+depends=(
+  "qbe-git"
+  "harec-git"
+)
+makedepends=(
+  "scdoc"
+  "git"
+)
+source=("${pkgname%-*}::git+https://git.sr.ht/~sircmpwn/hare")
+sha256sums=('SKIP')
+
+pkgver() {
+  cd "$srcdir/$_pkgname"
+
+  git describe --long --abbrev=7 2>/dev/null | sed 's/\([^-]*-g\)/r\1/;s/-/./g'
+}
+
+build() {
+  cd "$srcdir/$_pkgname"
+
+  cp "configs/linux.mk" config.mk
+  export LOCALVER=arch
+  make ARCH="$CARCH" PREFIX=/usr
+}
+
+check () {
+  cd "$srcdir/$_pkgname"
+
+  make ARCH="$CARCH" check
+  HAREPATH=. .bin/hare test
+}
+
+package() {
+  cd "$srcdir/$_pkgname"
+
+  make ARCH="$CARCH" PREFIX=/usr DESTDIR="$pkgdir" install
+}